An audio spectrum analyzer is a device that visualizes the frequency content of an audio signal. It represents the distribution of frequencies in a graphical form, typically displaying amplitude or power on the y-axis and frequency on the x-axis. This tool is commonly used in audio engineering, music production, and sound analysis for various purposes.
This time I will describe how to make an audio FFT spectrum analyzer on a 256x50 pixel VFD display.
These types of displays emit very bright light with high contrast and clear visibility from wide angles, and have a wonderful retro look.
The device is very simple to build and has only a few components:
- Arduino nano microcontroller
- GP1287 VFD display with resolution of 256x50 pixels
- stereo potentiometer
- two capacitors
- two resistors
- and Button
Thanks to the two libraries used (U8G2 and fix_fft), the code is very simple and can be easily modified. The audio input to the Arduino is on A0, with bias at the mid point by 10K to Ground and 10K to +5V. At the input we can also put a potentiometer to control the amplitude of the input signal.
First, let's look at the case when we bring a signal with a certain frequency and shape to the input. For this purpose, I will use the signal generator that is part of my oscilloscope.
The spectrogram clearly shows the fundamental signal, as well as its harmonics. I will test it with square and sine wave. As we change the frequency of the oscillator, so does the fundamental of the analyzer display. Here we can see that the frequency range of this instrument is from 0Hz to 4.5 KHz, where most of the music signals are found. However, the purpose of this device is not to perform any precise audio analyzes and measurements, but primarily has a visual function.
The following image shows how the device works in conditions when we bring a complex audio signal to the input.
Otherwise, the device has two modes of operation that can be changed with the push of a button, in one mode the bars are next to each other, and in the other there is a certain distance between them.
Finally, the entire assembly is housed in a suitable box. This is not a professional tool because it has relatively low resolution and frequency range, but can serve as a great educational tool and visualizer for some audio project.
#include "U8g2lib.h"
#include "fix_fft.h"
#include <SPI.h>
int buttonPin = 2;
int oldButtonVal = 0;
// u8g2 set up, bar, line position L & R
#define LINEY 40
#define LINEXL 0
#define LINEXR 256
#define SAMPLES 128
#define AUDIO A0
U8G2_GP1287AI_256X50_1_4W_SW_SPI u8g2(U8G2_R0, /* clock=*/ 13, /* data=*/ 11, /* cs=*/ 10, /* dc=*/ 9, /* reset=*/ 8);
//U8GLIB_ST7920_128X64_1X lcd(EN, RW, CS); // serial use, PSB = GND
char im[SAMPLES];
char data[SAMPLES];
int barht[SAMPLES];
int nPatterns = 2;
int lightPattern = 1;
void setup()
{
u8g2.begin(); // inti u8g2
u8g2.setContrast(25);
pinMode(2, INPUT_PULLUP);
}
void loop()
{
static int i, j;
int val;
// get audio data
for(i = 0; i < SAMPLES; i++)
{
val = analogRead(AUDIO)* 50; // 0-1023
data[i] = (char)(val/4 - 128); // store as char
im[i] = 0; // init all as 0
}
// run FFT
fix_fft(data, im, 7, 0);
// extract absolute value of data only, for 64 results
for(i = 0; i < SAMPLES/2; i++)
{
barht[i] = (int)sqrt(data[i] * data[i] + im[i] * im[i]);
}
for(i = 0, j = 0; i < SAMPLES/2; i++, j += 2)
{
barht[i] = barht[j] + barht[j + 1];
}
// u8g2 barchart
barchart(SAMPLES/4, barht); // plot SAMPLES / 4 = 32 as barchart gen cannot handle 128 bars
}
// plot line and bar at position and height
void barchart(int n, int bh[])
{
int i, s, w; // bars, spacing and width
s = (LINEXR - LINEXL) / n;
int buttonVal = digitalRead(buttonPin);
if (buttonVal == LOW && oldButtonVal == HIGH) {// button has just been pressed
lightPattern = lightPattern + 1;
}
if (lightPattern > nPatterns) lightPattern = 1;
oldButtonVal = buttonVal;
switch(lightPattern) {
case 1:
w = s / 2;
break;
case 2:
w = s / 1;
}
u8g2.firstPage();
do
{
u8g2.setFont(u8g2_font_6x12_tf);
u8g2.drawStr(80, 7, "FFT Audio Spectrum");
u8g2.drawLine(LINEXL, LINEY, LINEXR, LINEY);
u8g2.drawStr(0, LINEY + 10, "0");
u8g2.drawStr(50, LINEY + 10, "1k");
u8g2.drawStr(110, LINEY + 10, "2k");
u8g2.drawStr(164, LINEY + 10, "3k");
u8g2.drawStr(220, LINEY + 10, "4k");
u8g2.drawStr(240, LINEY + 10, "Hz");
for(i = 0; i < n; i++)
{
u8g2.drawBox(LINEXL + s * i, LINEY - bh[i], w, bh[i] + 1); // u8glib doesn't accept box height of 0
}
}while(u8g2.nextPage());
}
